/**********************************************************************************************************
**************BIBB/BAuA Erwerbstätigenbefragung 2024*******************************************************
*******Codieren des Goldthorpe-Erikson-Portocarero (Klassen)-Schemas***************************************
***************************für Erwerbstätige***************************************************************
****** aus der Berufsangabe, Stellung im Beruf und Stellung im Betrieb*************************************
******************Mit SV-Variablen nachbildbar*************************************************************
***********************************************************************************************************
Herkunft: BIBB-FDZ
Stataversion: 18 MP
Ben Jann (2019) ISCOGEN: "Stata module to translate ISCO codes"  Statistical Software Components S458665, Boston College Department of Economics, revised 08 Feb 2025. (Stand:20.11.2025)
John Hendrickx, (2004), ISKO: Stata module to recode 4 digit ISCO-88 occupational codes, Statistical Software Components, Boston College Department of Economics (Stand:20.11.2025)

!!!Hinweis: 
Das Vorgehen zur Bildung der Variable EGP für die Befragten (f100_egp) unterscheidet sich in der ETB 2024 von der ETB 2018. In der ETB 2024 werden zur Bildung die Stata Ados „iscogen" (Umsteiger ISCO08 in ISCO88) und „isko" (Rekodierung in EGP) verwendet.
Das Vorgehen in der ETB 2018 orientierte sich am Vorgehen im Mikrozensus (vgl. Brauns, Steinmann und Haun 2000) mit der KldB 92.
Die EGP-Variablen für die Eltern (f1609_egp, f1610_egp) werden in der ETB 2024 wie in der ETB 2018 auf Basis des Stata Ados „isko" (Rekodierung in EGP) gebildet. 
Quelle: Brauns, H., S. Steinmann, and D. Haun. 2000. "Die Konstruktion des Klassenschemas nach Erikson, Goldthorpe und Portocarero (EGP) am Beispiel nationaler Datenquellen aus Deutschland, Großbritannien und Frankreich." ZUMA-Nachrichten 46:7-63.
*/


**********Recodieren der ISCO88


ssc install ISCOGEN   						 //istallieren des ado's zur Erstellung der ISCO88
iscogen f100_isco88=isco88(f100_isco08)
iscogen f1609_isco88 =isco88(f1609_isco08)
iscogen f1610_isco88 =isco88(f1610_isco08)




ssc install ISKO							//installieren des ado's für das EGP
*************************************************************************************
*********Recodieren der Variable

***Stellung im beruf
gen sempl_b=.														
replace sempl_b=1 if Stib==4												//Stib=Stellung im Beruf 4=Stelbständig

gen sempl_v=.
replace sempl_v=0 if F1608==1											//F1608==bis 15 durchgängig mit Vater zusammen gelebt? 1==ja 2==nein
replace sempl_v=1 if F1611==3 & F1608==1								//F1611==berufliche Stellung Vater bzw. Mutter 3=Selbstständige
	
gen sempl_m=.
replace sempl_m=0 if F1608==2
replace sempl_m=1 if F1611==3 & F1608==2		

**Vorgesetztenfunktion
**Vorgesetztenfunktion
gen supvis_b=.														//F302 Anzahl der Mitarbeitenden, für die die Person Vorgesetzte/r ist
replace supvis_b=1 if F302==1
replace supvis_b=F302 if F302>=2& F302<=10
replace supvis_b=10 if F302>10
replace supvis_b=0 if F302==.
replace supvis_b=0 if F302==99999

gen supvis_v=.
replace supvis_v=1 if (F1612b==9 | F1612b==8)&(F1612==1)				//F1612==Übte Ihr Vater/Ihre Mutter eine Vorgesetztenfunktion aus? 1=Ja, 2=Nein, 3=Keine Angabe
replace supvis_v=1 if (F1612b==1)										//F1612= Für wieviele Mitarbeiter ist ihre Mutter/Vater Vorgesetzte/r 1=1-9, 2=10+, 8=kann ich nicht sagen, 9=keine Angabe1
replace supvis_v=10 if (F1612b==2)
replace supvis_v=0 if F1612b==.

gen supvis_m=.
replace supvis_m=1 if (F1612b==9 | F1612b==8)&(F1612==1)				//F1612==Übte Ihr Vater/Ihre Mutter eine Vorgesetztenfunktion aus? 1=Ja, 2=Nein, 3=Keine Angabe
replace supvis_m=1 if (F1612b==1)										//F1612= Für wieviele Mitarbeiter ist ihre Mutter/Vater Vorgesetzte/r 1=1-9, 2=10+, 8=kann ich nicht sagen, 9=keine Angabe
replace supvis_m=10 if (F1612b==2)
replace supvis_m=0 if F1612b==.


****EGP
iskoegp f100_egp , isko(f100_isco88) sempl(sempl_b) supvis(supvis_b)
iskoegp f1609_egp , isko(f1609_isco88) sempl(sempl_v) supvis(supvis_v)		//f1609_isco88==Erwerbsberuf Vater ISCO88 4-steller
iskoegp f1610_egp , isko(f1610_isco88) sempl(sempl_m) supvis(supvis_m)		//f1610_isco88==Erwerbsberuf Mutter ISCO88 4-steller

replace f100_egp=-1 if f100_isco08<0 | f100_isco08>=9910 & f100_isco08<.		//Sonderwerte über isco08 auf -1 "Kein gültiger Berufscode" gesetzt 
replace f1609_egp=-1 if f1609_isco08<0 | f1609_isco08>=9910 & f1609_isco08<.
replace f1610_egp=-1 if f1610_isco08<0 | f1610_isco08>=9910 & f1610_isco08<.

replace f100_egp=-4 if f100_isco88==110 | f100_isco88==2470 | f100_isco88==7139 
replace f1609_egp=-4 if f1609_isco88==110 | f1609_isco8==2470 | f1609_isco88==7139 
replace f1610_egp=-4 if f1610_isco88==110 | f1610_isco88==2470 | f1610_isco88==7139

**110=Soldate, in ado nicht vercodet, 2470+7139 ISCO88(com) Werte in ado nicht vercodet; >9910 Sonderwerte in ado nicht vercodet
******************************************************************************************

******************************************************************************************
******Labeln der Variablen
label var f100_egp "Aktueller Erwerbsberuf: EGP aus ISCO88"
label var f1609_egp "Beruf Vater: EGP aus ISCO88"
label var f1610_egp "Beruf Mutter: EGP aus ISCO88"

label def egp10 -4"nicht zuordenbar", add modify
******************************************************************************************
drop supvis_* sempl_*
******************************************************************************************
*Anpassen der Codierung um besser Vergleichbarkeit mit EGP Ererbsberuf herzustellen
******************************************************************************************
recode f100_egp f1609_egp f1610_egp (4=5) (5=6) (7=8) (8=9) (9=10) (10=11) (11=7) 
**************Labeln der Variablen
#delimit ;
label define EGP
-9 "keine Angabe"
-8 "weiß nicht"
-7 "trifft nicht zu"
-6 "ungültig"
-5 "verweigert"
-4 "nicht zuordenbar"
-1 "Kein gültiger Berufscode"
1 "I Higher grade professionals, administrators, and officials; managers in large industrial establishments; large proprietors"
2 "II Lower grade professionals, administrators, and officials; higher-grade technicians; managers in small industrial establishments; supervisors of non-manual employees"
3 "IIIa/b Routine non-manual employees, higher and lower grade"
5 "IVa Small proprietors and artisans with employees"
6 "IVb small self-employed without employees"									
7 "IVc Farmers and smallholders; other self-employed in primary production"
8 "V Lower-grade technicians, supervisors of manual workers"
9 "VI Skilled manual workers"
10 "VIIa Semi- and unskilled manual workers (not in agriculture)"
11 "VIIb Agricultural and other workers in primary production";
#delimit cr
label val f100_egp f1609_egp f1610_egp EGP


//Löschen der ICO88 Variablen
drop f100_isco88 f1609_isco88 f1610_isco88