******************************************************************************************
*******************BIBB/BAuA Erwerbstätigenbefragung 2006*********************************
*******************Codieren von*wissensintensive Berufen**********************************
*************************Variante 3*******************************************************
******************************************************************************************

******************************************************************************************
/*
Herkunft: BIBB-FDZ
Stataversion: 12.0 MP
Quelle:
Tiemann, M., (2009): Wissensintensive Berufe. Wissenschaftliche Diskussionspapiere des 
Bundesinstitut für Berufsbildung, 114.
*/
******************************************************************************************
*********************Recodieren der Variablen
foreach x of varlist EB92o EB1_92o{							//EB920=Erwerbsberuf KldB92 3-steller; EB1_92o=1. Erwerbsberuf KldB92 3-steller
gen h_`x'=`x'
recode h_`x' (12 61 80 150 176 194 220 221 245 252 265 266 268 270 273 274 276    ///
290 292 293 295 300 305 311 316 317 318 331 332 487 501 502 505 506 510 550 622   ///
625 627 651 839=1)(32 374 378 392 514 641 642 670 671 677 678 687 689 704 713 771 ///
801 802 911=2)(31 309 600 601 602 605 607 609 611 612 757 774 775 776 777 779 832 ///
833 843 862 871 872 873 874 879 880 882 884 885 887=3)(0=-1)
replace h_`x'=-4 if `x'>=991
replace h_`x'=0 if h_`x'>3
}
******************************************************************************************
****Umbenennen der Variablen
rename  h_EB92o  EB_wib3
rename  h_EB1_92o EB1_wib3
******************************************************************************************
*********************weitere nötige Umcodierung (missings anpassen)
replace EB_wib3=-4 if EB_wib3==-1
replace EB1_wib3=-4 if EB1_wib3==-1
replace EB1_wib3=. if  EB1_92g==.
******************************************************************************************
******Labeln er Variablen
label define wib3 0"nicht wissenensintensiv" -1"Filter" -4"nicht zuordenbar" ///
1"wissensintensiv Produktion" 2"wissensintensiv primäre DL" 3"wissensintensiv sekundäre DL"

label value *_wib3 wib3
label var EB1_wib3 "wissensintensiver Beruf dritte Definition 1. Beruf" 
label var EB_wib3 "wissensintensiver Beruf dritte Definition Erwerbsberuf"
******************************************************************************************