******************************************************************************************
*********************************BIBB-Übergangstudie 2011*********************************
*******************Codieren von*wissensintensive Berufen**********************************
*************************Variante 3*******************************************************
***************UF-Variablen nicht nachbildbar, SV Variablen benötigt*************************

******************************************************************************************
/*
Herkunft: BIBB-FDZ
Stataversion: 12.0 MP
Quelle:
Tiemann, M., (2009): Wissensintensive Berufe. Wissenschaftliche Diskussionspapiere des 
Bundesinstitut für Berufsbildung, 114.
*/
******************************************************************************************
*********************Recodieren der Variablen
foreach x of varlist v5014_kldb92_vater_3d v5022_kldb92_mutter_3d{								//v5014_kldb92_vater_3d=Erwerbsberuf Vater kldB 3-steller, v5022_kldb92_mutter_3d=Erwerbsberuf Mutter kldB 3-steller
gen h_`x'=`x'													
recode h_`x' (12 61 80 150 176 194 220 221 245 252 265 266 268 270 273 274 276 ///
290 292 293 295 300 305 311 316 317 318 331 332 487 501 502 505 506 510 550 622 ///
625 627 651 839=1)(32 374 378 392 514 641 642 670 671 677 678 687 689 704 713 771 ///
801 802 911=2)(31 309 600 601 602 605 607 609 611 612 757 774 775 776 777 779 832 ///
833 843 862 871 872 873 874 879 880 882 884 885 887=3)(0=-1)
replace h_`x'=0 if h_`x'>3
replace h_`x'=`x' if `x'<0
replace h_`x'=. if `x'==.
}

replace h_v5014_kldb92_vater_3d =-4 if v5014_kldb92_vater_4d>9900 & v5014_kldb92_vater_4d<.		//Deklarieren fehlender Werte
replace h_v5014_kldb92_vater_3d =-4 if v5014_kldb92_vater_3d==-111
replace h_v5022_kldb92_mutter_3d=-4 if v5022_kldb92_mutter_4d>9900 & v5022_kldb92_mutter_4d<.	//Deklarieren fehlender Werte
replace h_v5022_kldb92_mutter_3d=-4 if v5022_kldb92_mutter_3d==-111
******************************************************************************************
****Umbenennen der Variablen

rename h_v5014_kldb92_vater_3d  v5014_wib3
rename h_v5022_kldb92_mutter_3d v5022_wib3
******************************************************************************************
******Labeln er Variablen

#delimit ;
label define wib3 
-11 "Hausfrau, Hausmann"
-10 "In schulischer Ausbildung"
-9 "keine Angabe"
-8 "weiß nicht"
-7 "trifft nicht zu"
-6 "ungültig"
-5 "verweigert"
-1 "-1 Filter"
0"nicht wissenensintensiv" -4" -4 nicht zuordenbar" 
1"wissensintensiv Produktion" 2"wissensintensiv primäre DL" 
3"wissensintensiv sekundäre DL";
#delimit cr

label value *_wib3 wib3
label var v5022_wib3 "Berufstätigkeit Mutter: wissensintensiver Beruf 3. Definition" 
label var v5014_wib3 "Berufstätigkeit Vater: wissensintensiver Beruf 3. Definition" 
******************************************************************************************