************************************************************************************************************
*********************************BIBB-Übergangstudie 2011********************************************
*******************Codieren von*wissensintensive Berufen********************************************
*************************Variante 3***********************************************************************
**************Mit SUF-Variablen nicht nachbildbar, SV Variablen benötigt*************************

************************************************************************************************************

*Herkunft: BIBB-FDZ:
*PASW Statistics 18.
 * Quelle:
Tiemann, M., (2009): Wissensintensive Berufe. Wissenschaftliche Diskussionspapiere des 
Bundesinstitut für Berufsbildung, 114.

********************************************************************************************************************************************************************************.

compute v5014_wib3= v5014_kldb92_vater_3d.
compute v5022_wib3= v5022_kldb92_mutter_3d.

DO REPEAT wib3=v5014_wib3 to v5022_wib3.

recode wib3 
(12 61 80 150 176 194 220 221 245 252 265 266 268 270 273 274 276 
290 292 293 295 300 305 311 316 317 318 331 332 487 501 502 505 506 510 550 622 625 627 651 839=1)
(32 374 378 392 514 641 642 670 671 677 678 687 689 704 713 771 801 802 911=2)
(31 309 600 601 602 605 607 609 611 612 757 774 775 776 777 779 832 833 843 862 871 872 873 874 879 880 882 884 885 887=3)
(0=-1) (997 -111=-4).


if wib3>3 wib3=0.
formats wib3(f5.0).
END REPEAT.
 if v5014_kldb92_vater_2d <0 v5014_wib3=v5014_kldb92_vater_3d.
 do if (v5014_kldb92_vater_2d gt 9900).
recode v5014_wib3 (0=-4).
end if.
 if v5022_kldb92_mutter_2d <0 v5022_wib3=v5022_kldb92_mutter_3d.
 do if (v5022_kldb92_mutter_2d gt 9900).
recode v5022_wib3 (0=-4).
end if.

EXECUTE.
**Labeln.
VALUE LABELS v5014_wib3 v5022_wib3
-11 "Hausfrau, Hausmann"
-10 "In schulischer Ausbildung"
-9 "keine Angabe"
-8 "weiß nicht"
-7 "trifft nicht zu"
-6 "ungültig"
-5 "verweigert"
-4"nicht zuordenbar" 
-1 "Filter"
 0 'nicht wissenensintensiv' 
 1'wissensintensiv Produktion'
 2'wissensintensiv primäre DL'  
3'wissensintensiv sekundäre DL'.


VARIABLE LABELS v5014_wib3  'Berufstätigkeit Vater: wissensintensiver Beruf dritte Definition Erwerbsberuf' /v5022_wib3 'Berufstätigkeit Mutter: wissensintensiver Beruf dritte Definition 1. Beruf'.

Execute.